METHOD IF_UJ_CUSTOM_LOGIC~EXECUTE.


    DATA: LS_REC   TYPE REF TO DATA,
          LT_FINAL TYPE REF TO DATA,
          ORIG_AMOUNT TYPE UJ_SIGNEDDATA.


    FIELD-SYMBOLS:
      <L_ACCOUNT>    TYPE ANY, "Dimension
      <L_FLOW>       TYPE ANY, "Dimension
      <L_SIGNEDDATA> TYPE ANY, "Dimension - holding the value IT is Standard
      <LS_REC>       TYPE ANY,
      <LT_FINAL>     TYPE STANDARD TABLE.

    "Create the table <LT_FINAL> for collecting the new entries
    CREATE DATA LT_FINAL LIKE CT_DATA.
    ASSIGN LT_FINAL->* TO <LT_FINAL>.

    "Creating the Line structure
    CREATE DATA LS_REC LIKE LINE OF CT_DATA.
    ASSIGN LS_REC->* TO <LS_REC>.
    "Add your dimensions here
    ASSIGN COMPONENT 'ET_ACCOUNT' OF STRUCTURE <LS_REC> TO <L_ACCOUNT>. "Dimension ET_ACCOUNT is the dimension creating the BPC Model
    ASSIGN COMPONENT 'ET_FLOW' OF STRUCTURE <LS_REC> TO <L_FLOW>. "Dimension ET_FLOW is the dimension creating the BPC Model
    ASSIGN COMPONENT 'SIGNEDDATA' OF STRUCTURE <LS_REC> TO <L_SIGNEDDATA>. "Standard


    "Main loop where we generate two new records based on the Context (Either based on the default entry or based on the *XDIM_MEMBERSET
    "We are not using <L_FLOW>, but you can use it if you want
    LOOP AT CT_DATA INTO <LS_REC>.

      ORIG_AMOUNT = <L_SIGNEDDATA>. "Keeping the original amount

      IF <L_ACCOUNT> = 'PL4100'.    "Checking for specific member
        <L_ACCOUNT> = 'PL7200'.     "Assining to a different member
        <L_SIGNEDDATA> = ORIG_AMOUNT * '0.4'. "Changing the originating value
        APPEND <LS_REC> TO <LT_FINAL>. "Creating a new record with the same value as the original amount
        <L_ACCOUNT> = 'PL7300'.
        <L_SIGNEDDATA> = ORIG_AMOUNT * '0.2'. "
        APPEND <LS_REC> TO <LT_FINAL>.   "Creating a new record with differnt value and member
      ENDIF.

    ENDLOOP.

    CT_DATA = <LT_FINAL>. "Assigning the new records to the BPC BADI Internal Table which will write them to the Database

  ENDMETHOD.